Pierre/shipheart-qt
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

Import initial du projet shipheart_cm5

Browse Source
This commit is contained in:
Pierre
2026-08-13 09:19:38 +02:00
commit 53e47729fb
533 changed files with 127946 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files
config_groupe_elements.qml
+406
View File
@@ -0,0 +1,406 @@
//========================================================================================================================================================================
// CONFIG_GROUPE_ELEMENTS.QML
// Ce fichier traite la configuration des groupes d'éléments (circuits notamment)
// La page est appelée depuis la page config_ordre_elements.qml, en cliquant sur "+" ou par pression longue sur un groupe existant
//========================================================================================================================================================================
import QtQuick 2.12
import QtQml.Models
import qt.koriolan.shipheart 1.0
Shipheart_page {
id: page_config_groupe_elements
// Mis en forme :
readonly property double pourcentage_largeur_colonne_gauche: 0.75
readonly property double espace_colonnes_principales: 20
readonly property double pourcentage_hauteur_ligne_haut: 1
readonly property double espace_lignes_principales: 20
readonly property double affichage_hauteur_utile: shipheart_hauteur_page - shipheart_hauteur_bandeau_haut - shipheart_hauteur_bandeau_bas
readonly property int hauteur_ligne_formulaire: 60
readonly property double pourcentage_largeur_labels_formulaire: 0.4
readonly property int hauteur_bouton_droit: 80
readonly property double pourcentage_bandeau_bas_largeur_zone_retour: 1
readonly property int periode_init_raffraichissement_parametres: 1 // En ms
readonly property int periode_raffraichissement_parametres: 1000 // En ms
// Affichage :
property bool bouton_bandeau_bas_zone_retour_actif: false
property int protection_mode: 0
// Données :
property int type_source: shipheart_type_source_inconnu
property int id_groupe: 0
// Modèles :
// Note : les modèles chargés dans 'main.qml' n'ont pas à être rechargés dans les pages suivantes
//===========================================================
// Timer periode raffraichissement parametres :
//===========================================================
Timer {
id: timer_raffraichissement_parametres
interval: periode_init_raffraichissement_parametres
triggeredOnStart: false
running: true
repeat: true
onTriggered: {
if (interval == periode_init_raffraichissement_parametres) { // Premier passage, 1ms après le premier chargement
interval = periode_raffraichissement_parametres;
init_page();
}
else if (!bouton_bandeau_bas_zone_retour_actif) {
}
}
}
// Titre de la page :
Shipheart_titre_1 {titre:(id_groupe === 0) ? qsTr("Création d'un groupe") : qsTr("Modification d'un groupe"); hauteur: shipheart_hauteur_bandeau_haut}
//-------------------------------------------------------
// Ecran Haut - Gauche :
//-------------------------------------------------------
Rectangle {
id: zone_affichage_haut_gauche
x: 0
y: shipheart_hauteur_bandeau_haut;
width: (shipheart_largeur_page * pourcentage_largeur_colonne_gauche) - (espace_colonnes_principales / 2)
height: (affichage_hauteur_utile * pourcentage_hauteur_ligne_haut) - espace_lignes_principales;
color: "transparent"
ListView {
id: grille_principale
width: parent.width
height: parent.height
snapMode: GridView.SnapToRow // L'arret de l'affichage se fera sur une rangée entière
clip: true // Nécessaire pour que les Delegates s'arretent à l'intérieur de la GridView
model: modele_grille_principale
footer: Rectangle { // Permet de dégager la place suffisante en fin de GridView pour accéder même au dernier élément lorsque que clavier est déplié
height: shipheart_hauteur_clavier
color: "transparent"
}
ObjectModel {
id: modele_grille_principale
//-------------------------------------------------------------------------------
// Ligne de formulaire : Nom du groupe
Rectangle {
width: (shipheart_largeur_page * pourcentage_largeur_colonne_gauche) - (espace_colonnes_principales / 2)
height: visible ? hauteur_ligne_formulaire : 0
color: "transparent"
visible: true
Shipheart_formulaire_label {
text: qsTr("Nom du groupe")
width: parent.width * pourcentage_largeur_labels_formulaire
}
Shipheart_formulaire_textfield {
id: champ_formulaire_Nom
width: parent.width * (1 - pourcentage_largeur_labels_formulaire)
x: parent.width * pourcentage_largeur_labels_formulaire
}
Shipheart_formulaire_ligne_separation {
haut_bas_hautbas: shipheart_formulaire_ligne_separation_basse
}
}
}
}
}
//-------------------------------------------------------
// Ecran Droite :
//-------------------------------------------------------
Rectangle {
id: zone_affichage_droite
x: zone_affichage_haut_gauche.width + espace_colonnes_principales
y: shipheart_hauteur_bandeau_haut;
width: (shipheart_largeur_page * (1 - pourcentage_largeur_colonne_gauche)) - (espace_colonnes_principales / 2)
height: (affichage_hauteur_utile * pourcentage_hauteur_ligne_haut) - (espace_lignes_principales / 2);
color: "transparent"
Column {
anchors.fill: parent
spacing: 10
// Bouton Enregistrer :
Rectangle {
width: parent.width
height: hauteur_bouton_droit
color: shipheart_couleur_fond_bouton
radius: shipheart_rayon_bouton
visible:
// (!clavier.active) && // Si le clavier est replié... // SDIR #255
(champ_formulaire_Nom.text !== "") // Si le nom n'est pas vide...
Text {
anchors {
verticalCenter: parent.verticalCenter
horizontalCenter: parent.horizontalCenter
}
font.pixelSize: 20
text: (id_groupe === 0) ? qsTr("Créer le groupe") : qsTr("Enregistrer")
color: couleur_blanc_casse
}
MouseArea {
anchors.fill: parent
onClicked: {
shipheart_clic();
mise_a_jour(); // Mise à jour des données saisies dans la BDD
stackView.pop(); // Retour
}
}
}
// Bouton Supprimer :
Rectangle {
width: parent.width
height: hauteur_bouton_droit
color: shipheart_couleur_fond_bouton
radius: shipheart_rayon_bouton
visible: ((clavier.active) || // Si le clavier est déplié...
(id_groupe === 0)) // Si le groupe n'existe pas encore...
? false // ...on ne propose pas le bouton
: true
Text {
anchors {
verticalCenter: parent.verticalCenter
horizontalCenter: parent.horizontalCenter
}
font.pixelSize: 20
text: qsTr("Supprimer")
color: couleur_blanc_casse
}
MouseArea {
anchors.fill: parent
onClicked: {
shipheart_clic();
if (suppression() === 0) stackView.pop(); // Retour
}
}
}
}
}
//-------------------------------------------------------
// Bandeau bas :
//-------------------------------------------------------
Row {
x: 0
y: shipheart_hauteur_page - shipheart_hauteur_bandeau_bas;
width: shipheart_largeur_page;
height: shipheart_hauteur_bandeau_bas;
spacing: 5
padding: 5
//.................................................
// Bouton retour
//.................................................
Rectangle {
id: bandeau_bas_zone_retour
width: (parent.width * pourcentage_bandeau_bas_largeur_zone_retour) - (2 * parent.padding)
height: shipheart_hauteur_bandeau_bas - parent.topPadding - parent.bottomPadding;
radius: shipheart_rayon_bouton
color: shipheart_couleur_fond_bouton
Image {
source: "/images/icone_retour.png"
sourceSize.height: 30
anchors {
verticalCenter: parent.verticalCenter
horizontalCenter: parent.horizontalCenter
}
}
MouseArea { // Zone d'interaction. On est obligé de la mettre dans la grille pour que Rectangle et MouseArea soient frères ou parent/enfant ET qu'on n'occupe qu'un espace dans la grille.
id: mouse_area_bandeau_bas_zone_retour
anchors.fill: parent
onClicked: {
shipheart_clic();
stackView.pop()
}
}
}
}
//-------------------------------------------------------
// Boite d'info :
//-------------------------------------------------------
Shipheart_boite_dialogue {
id: boite_information
}
// Note : il est inutile de prévoir un Mousearea pour sortir de l'économiseur sur cette page puisqu'il
// est systématiquement bloqué pour toutes les pages lancées depuis 'Paramètres Avancés'.
//=============================================================================================================
// Init de la page
//=============================================================================================================
function init_page()
{
var req, res;
var nb;
//---------------------------------------------------------------------------------------
// Nom du groupe :
if (id_groupe > 0)
{
req = 'SELECT Nom FROM TB_Familles WHERE Cle_primaire=' + id_groupe + ' ';
//console.log("Requête = " + req)
res = bdd.requete_unique(req);
champ_formulaire_Nom.text = res[0];
}
else champ_formulaire_Nom.text = "";
}
//=============================================================================================================
// Mise à jour des valeurs saisies
//=============================================================================================================
function mise_a_jour()
{
var req;
if (id_groupe === 0) // Création :
{
// Insertion d'une nouvelle entrée dans la BDD :
req = 'INSERT INTO TB_Familles (Nom, Priorite_affichage, Type_source) VALUES ("' + champ_formulaire_Nom.text + '", 99, ' + type_source + ')';
//console.log("Requête = " + req)
bdd.requete_unique(req);
}
else // Modification
{
// Mise à jour des nouvelles valeurs dans la BDD :
req = 'UPDATE TB_Familles SET Nom="' + champ_formulaire_Nom.text + '" WHERE Cle_primaire=' + id_groupe + ' ';
//console.log("Requête = " + req)
bdd.requete_unique(req);
}
}
//=============================================================================================================
// Suppression d'un groupe
//=============================================================================================================
function suppression()
{
var req, res;
var nb, nb_masques;
var retour = 0;
var table_elements;
var nom_elements;
// Vérification que le groupe est vide :
switch(type_source)
{
//----------------------------------------------------
case shipheart_type_source_batteries:
table_elements = "TB_Batteries";
nom_elements = qsTr("batteries");
break;
//----------------------------------------------------
case shipheart_type_source_capteurs:
table_elements = "TB_Capteurs";
nom_elements = qsTr("capteurs");
break;
//----------------------------------------------------
case shipheart_type_source_circuits:
table_elements = "TB_Circuits";
nom_elements = qsTr("circuits");
break;
//----------------------------------------------------
case shipheart_type_source_reservoirs:
table_elements = "TB_Reservoirs";
nom_elements = qsTr("réservoirs");
break;
//----------------------------------------------------
default:
table_elements = "";
break;
}
if (table_elements !== "")
{
nb = 0;
req = 'SELECT COUNT(*) AS Nb FROM ' + table_elements + ' WHERE ID_Famille=' + id_groupe + ' ';
//console.log("Requête = " + req)
res = bdd.requete_unique(req);
nb = Number(res[0]);
if (nb === 0) // La table ne contient aucun élément lié à cette famille.
{
// Vérification que ce groupe n'est pas le dernier (on n'accepte pas de n'avoir AUCUN groupe) :
req = 'SELECT COUNT(*) AS Nb FROM TB_Familles WHERE Type_source=' + type_source + ' ';
//console.log("Requête = " + req)
res = bdd.requete_unique(req);
if (Number(res[0]) > 1) // Il reste d'autres groupes valides. On peut donc supprimer celle-ci :
{
req = 'DELETE FROM TB_Familles WHERE Cle_primaire=' + id_groupe + ' ';
//console.log("Requête = " + req)
bdd.requete_unique(req);
}
else // C'est le dernier groupe valide, on interdit donc sa suppression.
{
// Définition des paramètres de la boite de dialogue :
boite_information.niveau = 1;
boite_information.imageTitreSource = "/images/attention.png"
boite_information.message = qsTr("Ce groupe est le dernier encore valide.<br /><br />Vous ne pourrez le supprimer qu'après en avoir préalablement créé au moins un autre (il n'est pas possible de fonctionner sans aucun groupe de %1).").arg(nom_elements)
boite_information.open();
retour = -1;
}
}
else // La table contient encore des éléments liés à cette famille
{
// Recherche des éléments masqués :
req = 'SELECT COUNT(*) AS Nb FROM ' + table_elements + ' WHERE ID_Famille=' + id_groupe + ' AND Priorite_affichage_accueil<=0 ';
//console.log("Requête = " + req)
res = bdd.requete_unique(req);
nb_masques = Number(res[0]);
// Définition des paramètres de la boite de dialogue :
boite_information.niveau = 1;
boite_information.imageTitreSource = "/images/attention.png"
if (nb_masques === 0) boite_information.message = qsTr("Ce groupe comprend encore %1 %2.<br /><br />Il est nécessaire d'affecter ces %2 à un autre groupe avant de pouvoir le supprimer.").arg(nb).arg(nom_elements).arg(nb_masques);
else boite_information.message = qsTr("Ce groupe comprend encore %1 %2,<br />dont %3 configuré(s) comme \"masqué(s)\".<br /><br />Il est nécessaire d'affecter ces %2 à un autre groupe avant de pouvoir le supprimer.").arg(nb).arg(nom_elements).arg(nb_masques);
boite_information.open();
retour = -1;
}
}
return (retour);
}
}