Import initial du projet shipheart_cm5
This commit is contained in:
@@ -0,0 +1,514 @@
|
||||
//========================================================================================================================================================================
|
||||
// CONFIG_KORIOLAN.QML
|
||||
// Ce fichier traite les paramètres de configuration qui sont réservés à Koriolan
|
||||
// La page est appelée depuis la page parametres_avances.qml, en cliquant sur "Accès réservé Koriolan" depuis la colonne "Sécurité"
|
||||
// Note importante : ce menu n'est accéssible que si l'accés à été fait avec un code au moins de niveau Administrateur.
|
||||
//========================================================================================================================================================================
|
||||
import QtQuick 2.12
|
||||
import QtQml.Models
|
||||
|
||||
import qt.koriolan.shipheart 1.0
|
||||
|
||||
|
||||
|
||||
Shipheart_page {
|
||||
id: page_config_koriolan
|
||||
|
||||
|
||||
// Mis en forme :
|
||||
readonly property double pourcentage_largeur_colonne_gauche: 0.75
|
||||
readonly property double espace_colonnes_principales: 20
|
||||
readonly property double pourcentage_hauteur_ligne_haut: 0.2
|
||||
readonly property double espace_lignes_principales: 20
|
||||
readonly property double affichage_hauteur_utile: shipheart_hauteur_page - shipheart_hauteur_bandeau_haut - shipheart_hauteur_bandeau_bas
|
||||
|
||||
readonly property int hauteur_ligne_formulaire: 60
|
||||
readonly property double pourcentage_largeur_labels_formulaire: 0.6
|
||||
|
||||
readonly property int hauteur_bouton_droit: 80
|
||||
|
||||
readonly property double pourcentage_bandeau_bas_largeur_zone_retour: 1
|
||||
|
||||
|
||||
readonly property int periode_init_raffraichissement_parametres: 1 // En ms
|
||||
readonly property int periode_raffraichissement_parametres: 1000 // En ms
|
||||
|
||||
|
||||
|
||||
// Affichage :
|
||||
property bool bouton_bandeau_bas_zone_retour_actif: false
|
||||
property int mode_maj_firmwares: 0
|
||||
|
||||
|
||||
// Données :
|
||||
|
||||
|
||||
// Modèles :
|
||||
// Note : les modèles chargés dans 'main.qml' n'ont pas à être rechargés dans les pages suivantes
|
||||
|
||||
|
||||
//===========================================================
|
||||
// Timer periode raffraichissement parametres :
|
||||
//===========================================================
|
||||
Timer {
|
||||
id: timer_raffraichissement_parametres
|
||||
interval: periode_init_raffraichissement_parametres
|
||||
triggeredOnStart: false
|
||||
running: true
|
||||
repeat: true
|
||||
onTriggered: {
|
||||
if (interval == periode_init_raffraichissement_parametres) { // Premier passage, 1ms après le premier chargement
|
||||
interval = periode_raffraichissement_parametres;
|
||||
|
||||
init_page();
|
||||
}
|
||||
else if (!bouton_bandeau_bas_zone_retour_actif) {
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// Titre de la page :
|
||||
Shipheart_titre_1 {titre:qsTr("Accès réservé Koriolan"); hauteur: shipheart_hauteur_bandeau_haut}
|
||||
|
||||
//-------------------------------------------------------
|
||||
// Ecran Haut - Gauche :
|
||||
//-------------------------------------------------------
|
||||
Rectangle {
|
||||
id: zone_affichage_haut_gauche
|
||||
x: 0
|
||||
y: shipheart_hauteur_bandeau_haut;
|
||||
width: (shipheart_largeur_page * pourcentage_largeur_colonne_gauche) - (espace_colonnes_principales / 2)
|
||||
height: (affichage_hauteur_utile * pourcentage_hauteur_ligne_haut) - espace_lignes_principales;
|
||||
color: "transparent"
|
||||
|
||||
ListView {
|
||||
id: grille_principale
|
||||
|
||||
width: parent.width
|
||||
height: parent.height
|
||||
snapMode: GridView.SnapToRow // L'arret de l'affichage se fera sur une rangée entière
|
||||
clip: true // Nécessaire pour que les Delegates s'arretent à l'intérieur de la GridView
|
||||
model: modele_grille_principale
|
||||
footer: Rectangle { // Permet de dégager la place suffisante en fin de GridView pour accéder même au dernier élément lorsque que clavier est déplié
|
||||
height: shipheart_hauteur_clavier
|
||||
color: "transparent"
|
||||
}
|
||||
|
||||
ObjectModel {
|
||||
id: modele_grille_principale
|
||||
|
||||
//-------------------------------------------------------------------------------
|
||||
// Ligne de formulaire : Client spécifique
|
||||
Rectangle {
|
||||
width: parent.width
|
||||
height: visible ? hauteur_ligne_formulaire : 0
|
||||
color: "transparent"
|
||||
|
||||
Shipheart_formulaire_label {
|
||||
text: qsTr("Client spécifique")
|
||||
width: parent.width * pourcentage_largeur_labels_formulaire
|
||||
}
|
||||
|
||||
Shipheart_formulaire_combobox {
|
||||
id: champ_formulaire_Specifique_client
|
||||
model: ListModel { }
|
||||
width: parent.width * (1 - pourcentage_largeur_labels_formulaire)
|
||||
onActivated: {
|
||||
shipheart_clic();
|
||||
}
|
||||
}
|
||||
|
||||
Shipheart_formulaire_ligne_separation {
|
||||
haut_bas_hautbas: shipheart_formulaire_ligne_separation_basse
|
||||
}
|
||||
}
|
||||
|
||||
//-------------------------------------------------------------------------------
|
||||
// Ligne de formulaire : Mode maj firmwares
|
||||
Rectangle {
|
||||
width: parent.width
|
||||
height: visible ? hauteur_ligne_formulaire : 0
|
||||
color: "transparent"
|
||||
|
||||
Shipheart_formulaire_label {
|
||||
text: qsTr("Mode de mise à jour des firmwares")
|
||||
width: parent.width * pourcentage_largeur_labels_formulaire
|
||||
}
|
||||
|
||||
Shipheart_formulaire_combobox {
|
||||
id: champ_formulaire_Mode_maj_firmwares
|
||||
model: ListModel { }
|
||||
width: parent.width * (1 - pourcentage_largeur_labels_formulaire)
|
||||
onActivated: {
|
||||
shipheart_clic();
|
||||
}
|
||||
}
|
||||
|
||||
Shipheart_formulaire_ligne_separation {
|
||||
haut_bas_hautbas: shipheart_formulaire_ligne_separation_basse
|
||||
}
|
||||
}
|
||||
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
//-------------------------------------------------------
|
||||
// Ecran Milieu - Gauche :
|
||||
//-------------------------------------------------------
|
||||
Rectangle {
|
||||
id: zone_affichage_milieu_gauche
|
||||
x: 0
|
||||
y: shipheart_hauteur_bandeau_haut + zone_affichage_haut_gauche.height + espace_lignes_principales;
|
||||
width: (shipheart_largeur_page * pourcentage_largeur_colonne_gauche) - (espace_colonnes_principales / 2)
|
||||
height: (affichage_hauteur_utile * (1 - pourcentage_hauteur_ligne_haut)) - espace_lignes_principales;
|
||||
color: "transparent"
|
||||
|
||||
//-------------------------------------------------------------------
|
||||
// Grille pour afficher les valeurs des paramètres non configurables :
|
||||
GridView {
|
||||
id: grille_informations
|
||||
|
||||
width: parent.width
|
||||
height: parent.height
|
||||
cellWidth: parent.width;
|
||||
cellHeight: hauteur_ligne_formulaire
|
||||
snapMode: GridView.SnapToRow // L'arret de l'affichage se fera sur une rangée entière
|
||||
clip: true // Nécessaire pour que les Delegates s'arretent à l'intérieur de la GridView
|
||||
model: modele_grille_informations
|
||||
delegate: Rectangle {
|
||||
width: parent.width
|
||||
height: visible ? hauteur_ligne_formulaire : 0
|
||||
color: "transparent"
|
||||
|
||||
Shipheart_formulaire_label {
|
||||
text: model.nom_champ
|
||||
width: parent.width * pourcentage_largeur_labels_formulaire
|
||||
}
|
||||
Shipheart_formulaire_valeur_fixe {
|
||||
text: model.valeur_champ
|
||||
width: parent.width * (1 - pourcentage_largeur_labels_formulaire)
|
||||
x: parent.width * pourcentage_largeur_labels_formulaire
|
||||
}
|
||||
Shipheart_formulaire_ligne_separation {
|
||||
haut_bas_hautbas: shipheart_formulaire_ligne_separation_basse
|
||||
}
|
||||
}
|
||||
ListModel {
|
||||
id: modele_grille_informations
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
//-------------------------------------------------------
|
||||
// Ecran Droite :
|
||||
//-------------------------------------------------------
|
||||
Rectangle {
|
||||
id: zone_affichage_droite
|
||||
x: zone_affichage_haut_gauche.width + espace_colonnes_principales
|
||||
y: shipheart_hauteur_bandeau_haut;
|
||||
width: (shipheart_largeur_page * (1 - pourcentage_largeur_colonne_gauche)) - (espace_colonnes_principales / 2)
|
||||
height: (affichage_hauteur_utile * pourcentage_hauteur_ligne_haut) - (espace_lignes_principales / 2);
|
||||
color: "transparent"
|
||||
|
||||
|
||||
Column {
|
||||
anchors.fill: parent
|
||||
spacing: 10
|
||||
|
||||
// Bouton Enregistrer :
|
||||
Rectangle {
|
||||
width: parent.width
|
||||
height: hauteur_bouton_droit
|
||||
color: shipheart_couleur_fond_bouton
|
||||
radius: shipheart_rayon_bouton
|
||||
// visible: !clavier.active // SDIR #255
|
||||
Text {
|
||||
anchors {
|
||||
verticalCenter: parent.verticalCenter
|
||||
horizontalCenter: parent.horizontalCenter
|
||||
}
|
||||
font.pixelSize: 20
|
||||
text: qsTr("Enregistrer")
|
||||
color: couleur_blanc_casse
|
||||
}
|
||||
MouseArea {
|
||||
anchors.fill: parent
|
||||
onClicked: {
|
||||
shipheart_clic();
|
||||
mise_a_jour(); // Mise à jour des données saisies dans la BDD et reconfiguration par l'application pour prise en compte.
|
||||
stackView.pop();
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// Bouton Test matériel :
|
||||
Rectangle {
|
||||
width: parent.width
|
||||
height: hauteur_bouton_droit
|
||||
color: shipheart_couleur_fond_bouton
|
||||
radius: shipheart_rayon_bouton
|
||||
visible: !clavier.active
|
||||
Text {
|
||||
anchors {
|
||||
verticalCenter: parent.verticalCenter
|
||||
horizontalCenter: parent.horizontalCenter
|
||||
}
|
||||
font.pixelSize: 20
|
||||
text: qsTr("Tests matériel")
|
||||
color: couleur_blanc_casse
|
||||
}
|
||||
MouseArea {
|
||||
anchors.fill: parent
|
||||
onClicked: {
|
||||
shipheart_clic();
|
||||
stackView.push("shipheart_test_home.qml")
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
//-------------------------------------------------------
|
||||
// Bandeau bas :
|
||||
//-------------------------------------------------------
|
||||
Row {
|
||||
x: 0
|
||||
y: shipheart_hauteur_page - shipheart_hauteur_bandeau_bas;
|
||||
width: shipheart_largeur_page;
|
||||
height: shipheart_hauteur_bandeau_bas;
|
||||
spacing: 5
|
||||
padding: 5
|
||||
|
||||
//.................................................
|
||||
// Bouton retour
|
||||
//.................................................
|
||||
Rectangle {
|
||||
id: bandeau_bas_zone_retour
|
||||
width: (parent.width * pourcentage_bandeau_bas_largeur_zone_retour) - (2 * parent.padding)
|
||||
height: shipheart_hauteur_bandeau_bas - parent.topPadding - parent.bottomPadding;
|
||||
radius: shipheart_rayon_bouton
|
||||
color: shipheart_couleur_fond_bouton
|
||||
|
||||
Image {
|
||||
source: "/images/icone_retour.png"
|
||||
sourceSize.height: 30
|
||||
anchors {
|
||||
verticalCenter: parent.verticalCenter
|
||||
horizontalCenter: parent.horizontalCenter
|
||||
}
|
||||
}
|
||||
|
||||
MouseArea { // Zone d'interaction. On est obligé de la mettre dans la grille pour que Rectangle et MouseArea soient frères ou parent/enfant ET qu'on n'occupe qu'un espace dans la grille.
|
||||
id: mouse_area_bandeau_bas_zone_retour
|
||||
anchors.fill: parent
|
||||
onClicked: {
|
||||
shipheart_clic();
|
||||
stackView.pop()
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
// Note : il est inutile de prévoir un Mousearea pour sortir de l'économiseur sur cette page puisqu'il
|
||||
// est systématiquement bloqué pour toutes les pages lancées depuis 'Paramètres Avancés'.
|
||||
|
||||
|
||||
//=============================================================================================================
|
||||
// Init de la page
|
||||
//=============================================================================================================
|
||||
function init_page()
|
||||
{
|
||||
var req, res;
|
||||
var nb;
|
||||
var i;
|
||||
var nom_champ, valeur_champ;
|
||||
var specifique_client;
|
||||
|
||||
|
||||
modele_grille_informations.clear();
|
||||
|
||||
req = 'SELECT Nom, Valeur FROM TB_Configuration ORDER BY Cle_primaire';
|
||||
//console.log("req =" + req);
|
||||
nb = bdd.requete(req);
|
||||
|
||||
for (i = 0; i < nb; i ++)
|
||||
{
|
||||
res = bdd.lecture_ligne();
|
||||
if (!res.isEmpty)
|
||||
{
|
||||
switch(res[0])
|
||||
{
|
||||
case "Nb_jours_avant_suppression_historique": nom_champ = qsTr("Nombre jours avant suppression historique"); valeur_champ = res[1]; break;
|
||||
case "Nb_jours_avant_suppression_mesures": nom_champ = qsTr("Nombre jours avant suppression mesures"); valeur_champ = res[1]; break;
|
||||
case "Periode_sauvegarde_bdd": nom_champ = qsTr("Période de sauvegarde BDD"); valeur_champ = res[1]; break;
|
||||
case "Periode_check_download": nom_champ = qsTr("Période de vérification download"); valeur_champ = res[1]; break;
|
||||
|
||||
default: continue;
|
||||
}
|
||||
modele_grille_informations.append({"commande": false, "nom_champ": nom_champ, "valeur_champ": valeur_champ});
|
||||
}
|
||||
else break; // Ne devrait pas arriver....
|
||||
}
|
||||
|
||||
req = 'SELECT Nom, Valeur FROM TB_Systeme ORDER BY Cle_primaire';
|
||||
//console.log("req =" + req);
|
||||
nb = bdd.requete(req);
|
||||
|
||||
for (i = 0; i < nb; i ++)
|
||||
{
|
||||
res = bdd.lecture_ligne();
|
||||
if (!res.isEmpty)
|
||||
{
|
||||
switch(res[0])
|
||||
{
|
||||
case "Date_dernier_archivage_mesures": nom_champ = qsTr("Date de dernier archivage mesures"); valeur_champ = res[1]; break;
|
||||
|
||||
default: continue;
|
||||
}
|
||||
modele_grille_informations.append({"commande": false, "nom_champ": nom_champ, "valeur_champ": valeur_champ});
|
||||
}
|
||||
else break; // Ne devrait pas arriver....
|
||||
}
|
||||
|
||||
|
||||
//---------------------------------------------------------------------------------------
|
||||
// Specifique_client :
|
||||
|
||||
// Mise à jour depuis la BDD au cas où... :
|
||||
req = 'SELECT Valeur FROM TB_Configuration WHERE Nom="Specifique_client" ';
|
||||
res = bdd.requete_unique(req);
|
||||
shipheart_specifique_client = res[0].split(';') // Mémorisation de l'ensemble du tableau
|
||||
specifique_client = Number(shipheart_specifique_client[0]);
|
||||
|
||||
champ_formulaire_Specifique_client.model.clear();
|
||||
champ_formulaire_Specifique_client.model.append({"valeur": shipheart_specifique_client_tous, "texte": qsTr("Aucune spécificité") });
|
||||
champ_formulaire_Specifique_client.model.append({"valeur": shipheart_specifique_client_suncy, "texte": qsTr("Client Suncy Concept") });
|
||||
|
||||
// Positionnement de l'index sur la valeur en cours :
|
||||
i = recherche_index_valeur_modele(specifique_client, champ_formulaire_Specifique_client.model, "specifique_client");
|
||||
if (i === -1) champ_formulaire_Specifique_client.currentIndex = recherche_index_valeur_modele(shipheart_specifique_client_tous, champ_formulaire_Specifique_client.model, "specifique_client");
|
||||
else champ_formulaire_Specifique_client.currentIndex = i;
|
||||
|
||||
|
||||
|
||||
//---------------------------------------------------------------------------------------
|
||||
// Mode de mise à jour des firmwares :
|
||||
req = 'SELECT Valeur FROM TB_Configuration WHERE Nom="Mode_maj_firmwares" ';
|
||||
res = bdd.requete_unique(req);
|
||||
mode_maj_firmwares = Number(res[0]);
|
||||
|
||||
|
||||
champ_formulaire_Mode_maj_firmwares.model.clear();
|
||||
champ_formulaire_Mode_maj_firmwares.model.append({"valeur": 0, "texte": qsTr("Normal (si version installée est antérieure à la version en cours)") });
|
||||
champ_formulaire_Mode_maj_firmwares.model.append({"valeur": 1, "texte": qsTr("Différente (si version installée est différente de version en cours)") });
|
||||
champ_formulaire_Mode_maj_firmwares.model.append({"valeur": 2, "texte": qsTr("Toujours (à utiliser avec modération...)") });
|
||||
|
||||
// Positionnement de l'index sur la valeur en cours :
|
||||
i = recherche_index_valeur_modele(mode_maj_firmwares, champ_formulaire_Mode_maj_firmwares.model, "mode_maj_firmwares");
|
||||
if (i === -1) champ_formulaire_Mode_maj_firmwares.currentIndex = recherche_index_valeur_modele(0, champ_formulaire_Mode_maj_firmwares.model, "mode_maj_firmwares");
|
||||
else champ_formulaire_Mode_maj_firmwares.currentIndex = i;
|
||||
|
||||
}
|
||||
|
||||
|
||||
//=============================================================================================================
|
||||
// Mise à jour des valeurs saisies
|
||||
//=============================================================================================================
|
||||
function mise_a_jour()
|
||||
{
|
||||
var req;
|
||||
var specifique_client;
|
||||
var chaine_specifique_client = "";
|
||||
|
||||
|
||||
//-------------------------------------------------------------------------------------------------------------
|
||||
// Spécifique client :
|
||||
specifique_client = champ_formulaire_Specifique_client.model.get(champ_formulaire_Specifique_client.currentIndex).valeur;
|
||||
|
||||
if (Number(shipheart_specifique_client[0]) !== specifique_client) // Si le code client a changé :
|
||||
{
|
||||
switch(specifique_client)
|
||||
{
|
||||
default:
|
||||
case shipheart_specifique_client_tous:
|
||||
chaine_specifique_client = shipheart_specifique_client_tous;
|
||||
break;
|
||||
|
||||
case shipheart_specifique_client_suncy:
|
||||
chaine_specifique_client = shipheart_specifique_client_suncy;
|
||||
chaine_specifique_client += ";id_circuit_activation_moteur=0"
|
||||
break;
|
||||
}
|
||||
|
||||
// Mise à jour de la nouvelle valeur dans la BDD :
|
||||
req = 'UPDATE TB_Configuration SET Valeur="' + chaine_specifique_client + '" ';
|
||||
req += ' WHERE Nom="Specifique_client" '
|
||||
//console.log("Requête = [ " + req + "; ]");
|
||||
bdd.requete_unique(req);
|
||||
}
|
||||
|
||||
|
||||
//-------------------------------------------------------------------------------------------------------------
|
||||
// Mode de mise à jour des firmwares :
|
||||
if (mode_maj_firmwares !== champ_formulaire_Mode_maj_firmwares.model.get(champ_formulaire_Mode_maj_firmwares.currentIndex).valeur)
|
||||
{
|
||||
mode_maj_firmwares = champ_formulaire_Mode_maj_firmwares.model.get(champ_formulaire_Mode_maj_firmwares.currentIndex).valeur;
|
||||
|
||||
switch(mode_maj_firmwares)
|
||||
{
|
||||
case 0:
|
||||
case 1:
|
||||
case 2:
|
||||
// Mise à jour de la nouvelle valeur dans la BDD :
|
||||
req = 'UPDATE TB_Configuration SET Valeur="' + mode_maj_firmwares + '" ';
|
||||
req += ' WHERE Nom="Mode_maj_firmwares" '
|
||||
//console.log("Requête = [ " + req + "; ]");
|
||||
bdd.requete_unique(req);
|
||||
|
||||
break;
|
||||
|
||||
default:
|
||||
break;
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
|
||||
|
||||
|
||||
//------------------------------------------------------------------------------------------------------------------
|
||||
|
||||
// ATTENTION : le rechargement de la config ne suffira pas la plupart du temps. Il faudra procéder à un reset de ShipHeart...
|
||||
|
||||
// Demande de reconfiguration système via la BDD car on a modifié des valeurs de configuration :
|
||||
synchro_bdd(shipheart_type_synchro_config);
|
||||
}
|
||||
|
||||
//=============================================================================================================
|
||||
// Recherche de l'index d'une certaine valeur dans un modele
|
||||
//=============================================================================================================
|
||||
function recherche_index_valeur_modele(cible, modele, nom_modele)
|
||||
{
|
||||
var i;
|
||||
|
||||
for (i=0; i<modele.count; i ++)
|
||||
{
|
||||
if (modele.get(i).valeur === cible) break; // Cas où la valeur cible a été trouvée parmi les valeurs du modèle
|
||||
}
|
||||
if (i === modele.count)
|
||||
{
|
||||
console.log("Aucune valeur trouvée pour cible = [" + cible + "] du modèle = " + nom_modele);
|
||||
i = -1; // Cas où la valeur n'a pas été trouvée parmi les valeurs du modèle
|
||||
}
|
||||
//else console.log("Valeur trouvée : [" + i + "] pour cible = [" + cible + "] soit texte = [" + modele.get(i).texte + "]");
|
||||
return(i);
|
||||
}
|
||||
|
||||
|
||||
}
|
||||
|
||||
Reference in New Issue
Block a user